procedure TForm1.SaveHTMLSourceToFile(const FileName: string;
WB: TWebBrowser);
var
  PersistStream: IPersistStreamInit;
  FileStream: TFileStream;
  Stream: IStream;
  SaveResult: HRESULT;
begin
  PersistStream := WB.Document as IPersistStreamInit;
  FileStream := TFileStream.Create(FileName, fmCreate);
  try
    Stream := TStreamAdapter.Create(FileStream, soReference) as IStream;
    SaveResult := PersistStream.Save(Stream, True);
    if FAILED(SaveResult) then
      MessageBox(Handle, 'Fail to save HTML source', 'Error', 0);
  finally
    { В ответ на уничтожение объекта TFileStream, передаём
    soReference в конструктор TStreamAdapter. }
    FileStream.Free;
  end;
end;

uses
  WinInet;

procedure TForm1.Button1Click(Sender: TObject);
const
  BUF_SIZE = 65536;
var
  Internet, Connection, Request: HINTERNET;
  ErrorCode: Integer;
  Data: Pointer;
  Buf: array[0..BUF_SIZE - 1] of Byte;
  bytes_read: Cardinal;
begin
  Internet := InternetOpen('SAMPLE', INTERNET_OPEN_TYPE_PRECONFIG, nil, nil, 0);
  if not Assigned(Internet) then
    RaiseLastWin32Error;
  try
    Connection := InternetConnect(Internet, 'www.delphikingdom.com',
      INTERNET_INVALID_PORT_NUMBER, nil, nil, INTERNET_SERVICE_HTTP, 0, 0);
    if not Assigned(Connection) then
      RaiseLastWin32Error;
    try
      Request := HttpOpenRequest(Connection, 'GET', '/asp/answer.asp?IDAnswer=35254',
        nil, nil, nil, INTERNET_FLAG_KEEP_CONNECTION, 0);
      if not Assigned(Request) then
        RaiseLastWin32Error;
      try
        repeat
          HttpSendRequest(Request, nil, 0, nil, 0);
          Data := nil;
          ErrorCode := InternetErrorDlg(Handle, Request, ERROR_SUCCESS,
            FLAGS_ERROR_UI_FILTER_FOR_ERRORS or FLAGS_ERROR_UI_FLAGS_CHANGE_OPTIONS or
            FLAGS_ERROR_UI_FLAGS_GENERATE_DATA, Data);
        until ErrorCode <> ERROR_INTERNET_FORCE_RETRY;

        with TFileStream.Create('c:\delphikingdom.html', fmCreate) do
        try
          while InternetReadFile(Request, @Buf, BUF_SIZE, bytes_read) and (bytes_read > 0) do
            Write(Buf, bytes_read);
        finally
          Free;
        end;
      finally
        InternetCloseHandle(Request);
      end;
    finally
      InternetCloseHandle(Connection);
    end;
  finally
    InternetCloseHandle(Internet);
  end;
end;