ZeroMemory(@Buf, BufSize);

ZeroMemory(@Buf, BufSize * SizeOf(Char));

unit ToolsUnit;

// функции для работы с процессами и нитями

interface

uses
  SysUtils, Classes, Windows, stProcessMonitorUnit;

// преобразование пути из имени по устройству
function DevicePathToWin32Path(APath: String): String;
// получение имени исполняемого файла процесса
function GetProcessFileName(const APID: Cardinal): String;
// открытие процесса с минимально нужными правами
function OpenProcess(AID: Cardinal): THandle;
// открытие нити с минимально нужными правами
function OpenThread(AID: Cardinal): THandle;



//==============================================================================
implementation

var
  LibKernel32: THandle;
  LibPSApi: THandle;

const
  PROCESS_QUERY_LIMITED_INFORMATION =  $1000;
  THREAD_QUERY_LIMITED_INFORMATION =  $0800;
  THREAD_QUERY_INFORMATION =          $0040;

// преобразование пути из имени по устройству
function DevicePathToWin32Path(APath: String): String;
var
  C: Char;
  S: String;
  I: Integer;

  function FindChar(const AStr: String; AChar: Char; From: Integer): Integer;
  var
    Res: PChar;
  begin
    Result := 0;
    if From <= Length(AStr) then begin
      Res := StrScan(PChar(AStr) + From, AChar);
      if Assigned(Res) then Result := Res - PChar(AStr) + 1;
    end;
  end;

begin
  I := FindChar(APath, '\', 2);
  I := FindChar(APath, '\', I + 1);
  Result := Copy(APath, I, Length(APath));
  Delete(APath, I, Length(APath));
  for C := 'A' to 'Z' do
  begin
    SetLength(S, MAX_PATH);
    if QueryDosDevice(PChar(String(C) + ':'), PChar(S), MAX_PATH) <> 0 then
    begin
      S := PChar(S);
      if SameText(APath, S) then
      begin
        Result := C + ':' + Result;
        Exit;
      end;
    end;
  end;
  Result := '';
end;

// открытие процесса с минимально нужными правами
function OpenProcess(AID: Cardinal): THandle;
begin
  Result := Windows.OpenProcess(PROCESS_QUERY_LIMITED_INFORMATION or SYNCHRONIZE, False, AID);
  if Result = 0 then Result := Windows.OpenProcess(PROCESS_QUERY_INFORMATION or SYNCHRONIZE, False, AID);
end;

// открытие нити с минимально нужными правами
function OpenThread(AID: Cardinal): THandle;
begin
  Result := stProcessMonitorUnit.OpenThread(THREAD_QUERY_LIMITED_INFORMATION or SYNCHRONIZE, False, AID);
  if Result = 0 then Result := stProcessMonitorUnit.OpenThread(THREAD_QUERY_INFORMATION or SYNCHRONIZE, False, AID);
end;

// получение имени исполняемого файла процесса
function GetProcessFileName(const APID: Cardinal): String;
type
  TGetModuleFileNameEx = function (hProcess: THandle; hModule: HMODULE; lpFilename: PChar; nSize: DWORD): DWORD; stdcall;
  TQueryFullProcessImageName = function(hProcess: THandle; dwFlags: DWORD; lpExeName: PChar; var lpdwSize: Integer): BOOL; stdcall;
  TGetProcessImageFileName = function(hProcess: THandle; lpImageFileName: PChar; nSize: DWORD): DWORD; stdcall;
var
  QueryFullProcessImageName: TQueryFullProcessImageName;
  GetProcessImageFileName: TGetProcessImageFileName;
  GetModuleFileNameEx: TGetModuleFileNameEx;
  PH: THandle;
  Size: Integer;
begin
  Result := '';
  Size := MAX_PATH; //10240;
  QueryFullProcessImageName := GetProcAddress(LibKernel32, {$IFDEF UNICODE}'QueryFullProcessImageNameW'{$ELSE}'QueryFullProcessImageNameA'{$ENDIF}); // Do Not Localize
  GetProcessImageFileName := GetProcAddress(LibKernel32, {$IFDEF UNICODE}'GetProcessImageFileNameW'{$ELSE}'GetProcessImageFileNameA'{$ENDIF}); // Do Not Localize
  if not Assigned(GetProcessImageFileName) then
    GetProcessImageFileName := GetProcAddress(LibPSApi, {$IFDEF UNICODE}'GetProcessImageFileNameW'{$ELSE}'GetProcessImageFileNameA'{$ENDIF}); // Do Not Localize
  GetModuleFileNameEx := GetProcAddress(LibPSApi, {$IFDEF UNICODE}'GetModuleFileNameExW'{$ELSE}'GetModuleFileNameExA'{$ENDIF}); // Do Not Localize

  // Vista - QueryFullProcessImageName
  if Assigned(QueryFullProcessImageName) and (Result = '') then
  begin
    PH := OpenProcess(APID);
    if PH <> 0 then
    try
      SetLength(Result, Size);
      if not QueryFullProcessImageName(PH, 0, PChar(Result), Size) then
        Size := 0;
      SetLength(Result, Size);
    finally
      CloseHandle(PH);
    end;
  end;

  // XP - GetProcessImageFileName
  if Assigned(GetProcessImageFileName) and (Result = '') then
  begin
    PH := OpenProcess(APID);
    if PH <> 0 then
    try
      SetLength(Result, Size);
      SetLength(Result, GetProcessImageFileName(PH, PChar(Result), Length(Result)));
      if Result <> '' then Result := DevicePathToWin32Path(Result);
    finally
      CloseHandle(PH);
    end;
  end;

  // 2000 - GetModuleFileNameEx
  if Assigned(GetModuleFileNameEx) and (Result = '') then
  begin
    PH := Windows.OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ, False, APID);
    if PH <> 0 then
    try
      SetLength(Result, Size);
      SetLength(Result, GetModuleFileNameEx(PH, 0, PChar(Result), Length(Result)));
    finally
      CloseHandle(PH);
    end;
  end;
end;

initialization
  LibKernel32 := LoadLibrary('kernel32.dll');
  LibPSApi :=    LoadLibrary('psapi.dll');

finalization
  if LibKernel32 <> 0 then FreeLibrary(LibKernel32);
  if LibPSApi <> 0 then    FreeLibrary(LibPSApi);
end.

interface

const
  psapi = 'Psapi.dll';

function GetModuleFileNameEx(hProcess: THandle; hModule: HINST;
  lpFileName: PChar; nSize: DWORD): DWORD; stdcall;
function GetModuleFileNameExA(hProcess: THandle; hModule: HINST;
  lpFileName: PAnsiChar; nSize: DWORD): DWORD; stdcall;
function GetModuleFileNameExW(hProcess: THandle; hModule: HINST;
  lpFileName: PWideChar; nSize: DWORD): DWORD; stdcall;

function ProcessExeName(ProcessId: Integer): string;

implementation

function GetModuleFileNameEx; external psapi name 'GetModuleFileNameExA';
function GetModuleFileNameExA; external psapi name 'GetModuleFileNameExA';
function GetModuleFileNameExW; external psapi name 'GetModuleFileNameExW';

function ProcessExeName(ProcessId: Integer): string;
const
  BufSize = MAX_PATH;
var
  Buf: array[0..BufSize - 1] of Char;
  ResultLen: Integer;
  ProcessHandle: THandle;
begin
  Result := '';
  ProcessHandle := OpenProcess(PROCESS_QUERY_INFORMATION or PROCESS_VM_READ,
    True, ProcessId);
  if ProcessHandle <> 0 then
  begin
    try
      ZeroMemory(@Buf, BufSize);
      ResultLen := GetModuleFileNameEx(ProcessHandle, 0, Buf, BufSize);
      SetString(Result, Buf, ResultLen);
    finally
      CloseHandle(ProcessHandle);
    end;
  end;
end;