// TODO: есть небольшой косячок в этом компоненте: если ввести текст, СОВПАДАЮЩИЙ
// с PlaceHolder (руками, например), то он "исчезнет". Надо бы поправить, но мне пока
// подобные случаи не встречались, так что лень

unit PlaceHolder;

interface

Uses Forms,Controls,Graphics,StdCtrls;

Type
  TEdit=class(StdCtrls.TEdit)
  private
    fPlaceHolder:string;
    procedure SetPlaceholder(Value:string);
    function GetText:string;
    procedure SetText(Value:string);
    function IsActive:boolean;
  protected
    procedure DoEnter;override;
    procedure DoExit;override;
  public
    property PlaceHolder:string read fPlaceHolder write SetPlaceHolder;
    property Text:string read GetText write SetText;
  end;

implementation

{ TEdit }

procedure TEdit.DoEnter;
begin
  inherited;
  if inherited Text=PlaceHolder then begin
    inherited Text:='';
    Font.Color:=clWindowText;
  end;
end;

procedure TEdit.DoExit;
begin
  inherited;
  if inherited Text='' then begin
    inherited Text:=PlaceHolder;
    Font.Color:=clGray;
  end;
end;

function TEdit.GetText: string;
var
  S:string;
begin
  S:=inherited Text;
  if S=PlaceHolder then Result:=''
  else Result:=S;
end;

function TEdit.IsActive: boolean;
var
  Wc:TWinControl;
begin
  Wc:=Parent;
  while (Wc<>nil) and (not (Wc is TCustomForm)) do
    Wc:=Wc.Parent;
  Result:=(Wc<>nil)and(TForm(Wc).ActiveControl=Self);
end;

procedure TEdit.SetPlaceholder(Value: string);
begin
  fPlaceHolder:=Value;
  if IsActive then exit;
  if Text='' then begin
    inherited Text:=PlaceHolder;
    Font.Color:=clGray;
  end;
end;

procedure TEdit.SetText(Value: string);
begin
  inherited Text:=Value;
  if IsActive then exit;
  if Value='' then begin
    Font.Color:=clGray;
    inherited Text:=PlaceHolder;
  end else Font.Color:=clWindowText;
end;

end.