Alexander Shagin
дата публикации 02-11-2006 06:18

---

Версия для печати

Введение

Среда Borland Delphi (версии 6 и 7) предоставляет достаточно удобные инструменты по созданию Web Services application. В сочетании с технологией Midas у программиста есть очень эффективный инструмент по созданию N-звенных приложений доступа к корпоративным БД. Тем не менее реализация Web Services в Delphi содержит некоторые существенные ограничения, которые, в целом оправданы, но при переходе на новую платформу, будут вызывать у программистов, привыкших работать с TDCOMConnection, TSocketConnection и т.п. дополнительные сложности. SOAP Server applications — это, в общем случае, statelss приложения — сервер не хранит информацию о предыдущих вызовах клиента, что не позволяет использовать привычный подход и технологию программирования, а тем более говорить о прозрачном переходе на новый тип соединения(Например,так как это происходит при переходе с TDCOMConnection на TSocketConnection или наоборот). Конечно, отсутствие statefull-объектов на сервере оправдывается тем, что потенциально Web Services должны будут обрабатывать огромное количество входящих соединений, и выделение для каждого из них оперативной памяти приведет, в конце концов, к выводу сервера или сервиса из строя, но тем не менее отсутствие прозрачного механизма портации существующих проектов(если, конечно, таковая вообще требуется) может остановить от реализации этой идеи даже очень опытных программистов.

В процессе работы у нас возникла следующая задача. Корпоративная система работала в пределах локальной сети. Соеденение клиентов осуществлялось с помощью SocketConnection, что обеспечивало вполне приличную скорость и масштабируемость. Со временем появились новые удаленные рабочие места, но соеденение по локальной сети установить уже не было возможности, только Internet. Требовалось обеспечить работу пользователей в точности с тем же набором приложений (чтобы не приходилость дополнительно тратить времени на обучение по работе с новым софтом или на дополнительную организацию их взаимодействия с основной корпоративной системой), который они использовали ранее. Для коммуникации клиентских приложений с основным сервером идеально подходил SOAP-протокол, но отсутствие statefull соединений могло сильно затянуть время адаптации серверов приложений. Посколько в параллельных проектах уже был опыт использования Web Services , и появление вышеобозначенных проблем вполне предсказывалось, велась разработка механизма прозрачного перевода MIDAS-серверов и клиентов на использование протокола SOAP. Детали, проблемы и подходы в решении этой задачи я бы и хотел осветить в этой статье.

Проблемы и их решения

Основной проблемой, с которой приходится изначально бороться — это отсутствие сессионности между вызовами клиента. От кого пришел запрос, в общем случае, однозначно понять практически невозможно. В интернете содержится достаточно много публикаций на эту тему и подход (пример: Managing sessions with Delphi 6 Web services, Building Real-Life Web Services), в общем-то, для решения проблемы един: создание на стороне сервера постоянно существующий объект: менеджер сессий. Как следствие — application server должен быть постоянно загружен на web-сервере или самостоятельно выполнять его функцию.

Следующая проблема — это обеспечение прозрачного вызова базовых методов интерфейса IAppServer с клиента соответствующих методов требуемого провайдера(TCustomProvider) на сервере в контексте сессии. Решением данной проблемы является создание наследника от TCustomRemoteServer, который инкапсулирует данные(контекст сессии) и методы по взаимодействию с менеджером сессий средствами SOAP-протокола. На стороне сервера создается наследник от TInvokableClass (TSOAPSessionManeger), и соответствующий ему IInvokable интерфейс ISOAPSessionManeger, который реализует базовые, но модифицированные, методы интерфейса IAppServer, и дополнительные методы, необходимые для авторизации, контроля состояния и др.

ISOAPSessionManeger = interface(IInvokable)
  ['{59AD0E15-EF0F-4DF3-A782-18B5FEC70AC4}']
  {IAppServer support}
  function  WS_AS_ApplyUpdates(const SessionID:WideString; const ProviderName: WideString;
                       Delta: OleVariant; MaxErrors: Integer; out ErrorCount: Integer;
                       var OwnerData: OleVariant): OleVariant;  stdcall;
  function  WS_AS_GetRecords(const SessionID:WideString; const ProviderName: WideString;
                       Count: Integer; out RecsOut: Integer; Options: Integer;
                       const CommandText: WideString; var Params: OleVariant;
                       var OwnerData: OleVariant): OleVariant; stdcall;
  function  WS_AS_DataRequest(const SessionID:WideString; const ProviderName: WideString;
                       Data: OleVariant): OleVariant; stdcall;
  function  WS_AS_GetProviderNames(const SessionID:WideString): TWideStringDynArray;
                       stdcall;
  function  WS_AS_GetParams(const SessionID:WideString;const ProviderName: WideString;
                       var OwnerData: OleVariant): OleVariant; stdcall;
  function  WS_AS_RowRequest(const SessionID:WideString; const ProviderName: WideString;
                       Row: OleVariant; RequestType: Integer;
                       var OwnerData: OleVariant): OleVariant; stdcall;
  procedure WS_AS_Execute(const SessionID:WideString; const ProviderName: WideString;
                       const CommandText: WideString; var Params: OleVariant;
                       var OwnerData: OleVariant); stdcall;
  {Authorithation support}
  function  WS_Login(const AUserName, APassword: WideString ;
                       var SessionID, ErrMsg:WideString):Integer; stdcall;
  function  WS_Logout(const SessionID:WideString):Integer; stdcall;
  function  WS_GetSessionState(const SessionID:WideString):Integer;stdcall;
  {Data-exchange support}
  function  WS_GetValue(const SessionID, AName: WideString):OleVariant;stdcall;
  procedure WS_SetValue(const SessionID, AName: WideString; const AData: OleVariant);
                       stdcall;
  function  WS_CallMethod(const SessionID, MethodName: WideString;
                       const Params: OleVariant):OleVariant;stdcall;
end;

Базовым понятием в данной модели является понятие сессии (класс TWSSession) . Сессия — это объект, который идентефицирует клиетское соединение на стороне сервера, ассоциирует с ним наборы модулей данных(наследники TDataModule), обеспечивает регистрацию провайдеров из соответствующих модулей, вызов базовых методов интерфейса IAppServer, и методы авторизации для конкретной сессии. Ключевые понятия сессии:

• SessionID — id сессии в менеджере сессий.
• UserName, Password — данные для авторизации.
• AppID — наименование набора классов(модулей данных), которые будут создаваться при регистрации нового клиента. AppID вместе с SessionID клиент передается в заголовке каждого SOAP-сообщения на сервер.

Для того, чтобы определить, какие модули данных необходимо создавать для данного AppID — их классы предварительно регистрируются. Поскольку интерфейс ISOAPSessionManeger является своеобразным "переходником" между клиентом и стандартным интерфейсами IAppServer посредством менеджера сессий, обеспечивая бинарную совместимость передаваемых пакетов данных, что позволяет прозрачно вызывать методы провайдеров уже в контексте сессии(т.е. только из тех дата-модулей, которые определены для данного AppID в конкретной сессии)

Вызов методов IInvokable интерфейсов в котнексте сессии. Для решения этой проблемы пришлось изменить стандартное поведение класса TSoapPascalInvoker. При определении экземпляра объекта для выполнения метода, запрашиваемого клиентом интерфейса, Delphi ищет в собственном реестре(объект InvRegistry) класс, его реализующий, а затем создает его экземпляр(Per request), или процедуру, возвращающую ссылку на этот объект(Global). Поскольку в каждом SOAP-сообщении содержится SessionID, можно определить сессиию клиента, и как следствие, получить ссылки на дата-модули, существующие в ее контексте. Далее находим дата-модуль, реализующий запрашиваемый интерфейс и возвращаем на него ссылку. Далее работает стандартная схема, а метод уже вызывается именно в контексте сессии. Поскольку предварительно мы реализуем стандартный код, вышеприведенные изменения ни в коем случае не изменяют установленного поведения компонентов и их методов. Таким образом задача создания своих собственных state-full объектов с поддержкой сессий становится тривиальной задачей: Создание наследника TDataModule TMyDM, объявление IInvokeble интерфейса IMyIntf и его регистрация в InvRegistry, включение интерфеса IMyIntf в класс TMyDM и его регистрация в системе(WSReg.RegisterDataModule(TMyDM,'MyApp')), реализация методов интерфейса.

Неожиданной оказалась проблема автоматического включения в каждый заголовок SOAP-сообщения идентификационной информации. Класс TRIO не содержит событий, которые позволили добавить в заголовок нужную информацию c использованием сдандартных для этого методов(Класс TSOAPHeader). Событие OnBeforeExecute вызывается уже полсе того, как заголовки упакованы в сообщение. Исходный код TRIO пришлось модифицировать, добавлением события OnBeforeRequest(добавить метод DoBeforeRequest) и полученный класс TWSRIO использовать в классе TwssSoapConnection(наследник TCustomRemoteServer, реализующий взаимодействие сервером приложений). Вызов удаленных методов интерфейсов предпочтительно осуществлять с использованием этого класса, или же, для компонента TRIO самостоятельно добавлять нужные заголовки(класс TWSSHeader).

Как следствие, вышеприведенных изменений вполне достаточно как для портации серверных приложений на базе TRemoteDataModule под Web Services, так и создания новых state-full, state-less Web Services приложений в привычных для программиста условиях.

Дополнительные особенности

В процессе работы, к стандартному механизму SOAP, были добавлены такие возможности как:

• сжатие передаваемого по сети контента(используется библитека ZLib);
• так называемые NotifyEvents для модулей данных.
• вызов удаленных методов минуя IInvokable интерфейсы(wssIntf.pas : IModuleAuth.CallMethod).

Реализация

Исходники и примеры прилагаются. Для реализации примера установите у себя пакет wss.dpk. Пропишите необходимые пути в Library Path.

Пример

Сервер

Сервер будем реализовывать как standalone Web Service(Требуется библиотека Indy).

1. Создаем консольное приложение.
2. Добавляем к нему TDataModule.
3. Объявляем интерфейс(Классом реализации будет наш дата-модуль):

 { Invokable interface IWSSTest }

 unit WSSTestIntf;

 interface

 uses InvokeRegistry, Types, XSBuiltIns;

 type

   { Invokable interfaces must derive from IInvokable }
   IWSSTest = interface(IInvokable)
   ['{15907745-68B1-47A3-86A6-9EF2A3530493}']

     { Methods of Invokable interface must not use the default }
     { calling convention; stdcall is recommended }
     function TestMethod(const s : string): string ;stdcall;
   end;

 implementation

 initialization
   { Invokable interfaces must be registered }
   InvRegistry.RegisterInterface(TypeInfo(IWSSTest));

 end.

4. Реализуем поддержку нашего интерфейса в дата-модуле:

 unit Unit2;

 interface

 uses
   SysUtils, Classes, WSSTestIntf,
   WSObj{WSS Core};

 type
   TDataModule2 = class(TDataModule, IWSSTest, IWSSessionNotifyEvents)
   private
     { Private declarations }
     //добавление совершенно не обязательно, но удобно, а иногда и полезно:)
     procedure  WSSessionNotifyEvent(const SessionClient : TWSSesClient;
                                              const EventName : string;
                                              const Data: OleVariant);
   public
     { Public declarations }
     function TestMethod(const s : string): string ;stdcall;
   end;

 var
   DataModule2: TDataModule2;

 implementation

 {$R *.dfm}

 { TDataModule2 }

 function TDataModule2.TestMethod(const s: string): string;
 begin
   Result := 'Hello from server: '+ s;
   writeln('Method call: '+ s);
 end;

 procedure TDataModule2.WSSessionNotifyEvent(
   const SessionClient: TWSSesClient; const EventName: string;
   const Data: OleVariant);
 begin
   writeln('EVENT:',EventName,' - sessionid:',SessionClient.SessionID);
 end;

 end.

5. Модифицируем dpr-файл как показано ниже.

 program Project2;

 {$APPTYPE CONSOLE}

 uses
   SysUtils,
   IndyHttpServerApp,{Под Apache2 заменить на Apache2ServerApp}
   WSSTestIntf in 'WSSTestIntf.pas',
   Unit2 in 'Unit2.pas' {DataModule2: TDataModule};

 begin
   { TODO -oUser -cConsole Main : Insert code here }
   ServerApplication.Initialize;
   {register TDataModule2 class for AppID="TEST"}
   ServerApplication.RegisterDataModuleClass(TDataModule2,'TEST');
   ServerApplication.Run;
 end.

6. Готово. Запускаем сервер.
7. Видим Service Info Page страницу по адресу: http://localhost:8888/

Клиент

1. Создаем новый проект.
2. На форме распологаем компонент TwssSoapConnection. Устанавливаем значения свойств как приведено на скриншоте.


3. При помощи утилиты WSDL Importer импортируем в наш проект модуль с описанием интерфейса IWSSTest(получаем модуль IWSSTest1.pas).
4. Устанавливаем: wssSoapConnection1.URL=http://localhost:8888/soap, wssSoapConnection1.AppID="TEST" и заполняем поля wssSoapConnection1.SessionUserName и wssSoapConnection1.SessionPassword.
5. Пишем обработчики для кнопок:

 unit Unit1;

 interface

 uses
   Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
   Dialogs, StdCtrls, DB, DBClient, wssSoapConn;

 type
   TForm1 = class(TForm)
     wssSoapConnection1: TwssSoapConnection;
     Button1: TButton;
     Label1: TLabel;
     Button3: TButton;
     procedure Button1Click(Sender: TObject);
     procedure Button2Click(Sender: TObject);
     procedure Button3Click(Sender: TObject);
   private
     { Private declarations }
   public
     { Public declarations }
   end;

 var
   Form1: TForm1;

 implementation

 uses IWSSTest1;

 {$R *.dfm}

 procedure TForm1.Button1Click(Sender: TObject);
 begin
   wssSoapConnection1.Open;
   Label1.Caption := wssSoapConnection1.SessionID;
 end;

 procedure TForm1.Button2Click(Sender: TObject);
 begin
   wssSoapConnection1.Close;
 end;

 procedure TForm1.Button3Click(Sender: TObject);
 begin
   ShowMessage( (wssSoapConnection1.RIO as IWSSTest).TestMethod('Client.'));
 end;

 end.

6. Готово. Запускаем.
Клиент:


7. Сервер:

Переход от TXXXConnection к TwssSoapConnection

Клиент

1. TXXXConnection заменяется на TwssSoapConnection.
2. Вызовы методов через TCustomRemoteServer.AppServer заменяются на TwssSoapConnection.RIO as IMyAppIntf.

Сервер

1. Создаем серверный проект как показано в примере.
2. Добавляем к проекту TRemoteDataModule.(Меняем наследника на TDataModule)
3. Убираем все, что связано с DCOM.(Factrory и прочее...)
4. На базе You Project_TLB.pas создаем IInvokeble интерфейс и объявляем его поддержку для модуля данных.
5. Выполняем ServerApplication.RegisterDataModule(TMyDM,'MyApp');

Заключение

Все вышеизложенное — это всего лишь субъективный взгляд на решение этой задачи. Здесь приведен лишь беглый обзор достаточно большой работы. Кому же эта тема интересна или интересуют подробности работы предложенного механизма, есть что добавить, а особенно покритиковать(это основная цель публикации) просьба писать в обсуждении статьи.

• Примеры к статье (112 K) обновление от 11/2/2006 6:22:00 AM